Cách sử dụng hàm Search, tìm kiếm trong Excel và Ví dụ minh họa

Tìm hiểu cách sử dụng hàm SEARCH để tìm vị trí của một chuỗi văn bản hoặc ký tự cũng như trích xuất một chuỗi con (substring) cụ thể trong Excel.

Hàm SEARCH là một hàm văn bản tìm kiếm một ký tự hoặc chuỗi con cụ thể trong một chuỗi hoặc văn bản khác và trả về vị trí của nó. Nói cách khác, nó định vị một từ trong một từ khác và vị trí của nó trong ô dưới dạng một số nguyên.

Ví dụ: nếu bạn sử dụng hàm SEARCH để tìm vị trí của chữ cái ‘s’ hoặc văn bản ‘son’ trong từ “Jackson”, nó sẽ trả về 5. Nó sẽ chỉ trả về vị trí bắt đầu của chuỗi tìm kiếm trong ô đã tìm kiếm.

Hàm SEARCH hiếm khi được sử dụng một mình, nó thường được sử dụng cùng với FIND, MID, LEFT, ISNUMBER và các hàm khác. Trong bài viết này, chúng tôi sẽ giải thích hàm SEARCH là gì, cách sử dụng nó và cách sử dụng hàm SEARCH kết hợp với các hàm khác trong Excel.

Hàm SEARCH trong Excel

Hàm SEARCH tìm kiếm một chuỗi văn bản hoặc ký tự trong một chuỗi văn bản khác và trả về vị trí bắt đầu của chuỗi tìm kiếm trong ô được chỉ định hoặc chuỗi đã cho.

Cú pháp của hàm SEARCH trong Excel

=SEARCH (find_text, within_text, [start_num])
  • find_text (bắt buộc) là ký tự hoặc chuỗi / văn bản mà bạn đang tìm kiếm.
  • within_text(bắt buộc) là nơi bạn đang tìm kiếm find_text. Nó thường là tham chiếu ô chứa chuỗi văn bản mà chúng ta cần tìm kiếm. Tuy nhiên, bạn cũng có thể nhập chuỗi trực tiếp vào công thức.
  • [start_num](tùy chọn) chỉ định vị trí trong chuỗi within_text từ nơi bạn muốn bắt đầu tìm kiếm. Nếu bị bỏ qua, tìm kiếm sẽ bắt đầu từ ký tự đầu tiên của chuỗi within_text.

Hàm SEARCH không phân biệt chữ hoa chữ thường. Nếu bạn đang tìm kiếm một đối sánh phân biệt chữ hoa chữ thường, bạn có thể sử dụng hàm FIND. Nếu hàm tìm thấy nhiều kết quả phù hợp cho từ tìm kiếm, nó sẽ chỉ trả về vị trí của từ đầu tiên.

Chức năng Search cũng hỗ trợ các toán tử ký tự đại diện sau:

  • Dấu hỏi (?)  Được sử dụng để so khớp bất kỳ ký tự hoặc chữ cái đơn lẻ nào với chuỗi văn bản.
  • Dấu hoa thị (*)  được sử dụng để so khớp bất kỳ số ký tự nào với chuỗi.
  • Dấu ngã (~)   được sử dụng để khớp với dấu chấm hỏi hoặc dấu hoa thị thực tế. Nhập dấu ngã (~) trước hai ký tự đại diện còn lại để tìm chúng.

Tìm kiếm một ký tự hoặc văn bản trong chuỗi văn bản ngay từ đầu

Bạn có thể sử dụng hàm SEARCH để tìm kiếm một ký tự hoặc văn bản / từ cụ thể trong chuỗi văn bản ngay từ đầu và trả về vị trí của nó. Nó tìm kiếm chuỗi từ ký tự đầu tiên, từ trái sang phải, đến cuối chuỗi trong ô.

Quảng cáo

Để tìm kiếm một ký tự hoặc từ cụ thể trong chuỗi văn bản, hãy thử công thức sau:

=SEARCH("Angeles",A2)

hoặc là

Để tìm kiếm từ đầu chuỗi văn bản, bạn có thể bỏ qua đối số cuối cùng (start_num) hoặc đặt nó là 1:

=SEARCH("Angeles",A2,1)

Công thức trên tìm kiếm văn bản ‘Angeles’ bắt đầu từ ký tự đầu tiên trong chuỗi ‘Los Angeles’ (A2) và trả về vị trí của điểm bắt đầu của văn bản được tìm kiếm (Angeles) – 5.

Bạn cũng có thể sử dụng tham chiếu ô cho đối số find_text trong công thức:

=SEARCH(D3,A11,1)
Cảm ơn đã đọc bài viết tại saohaivuong .com, mời bạn theo dõi những tin tức mới nhất trên FB
Quảng cáo

Tìm kiếm phân biệt chữ hoa chữ thường

Như chúng tôi đã đề cập trước đó, hàm SEARCH không phân biệt chữ hoa chữ thường, bạn có thể tìm kiếm từ ‘SaLt’, ‘SALT’ hoặc ‘Salt’ bằng cách sử dụng công thức và nó sẽ trả về cùng một kết quả cho dù đối số find_text hoặc within_text là trường hợp nào sử dụng.

Tìm kiếm (các) ký tự hoặc văn bản trong chuỗi văn bản  từ vị trí bắt đầu cụ thể

Hàm SEARCH cũng có thể được sử dụng để tìm vị trí của một từ hoặc văn bản trong một chuỗi bằng cách bắt đầu tìm kiếm tại một điểm cụ thể của inside_text thay vì ký tự đầu tiên. Bằng cách chỉ định số bắt đầu (start_num) trong công thức, bạn có thể cho hàm biết vị trí bạn muốn bắt đầu tìm kiếm.

Xem thêm :

Ví dụ 1:

Để tìm kiếm một từ từ một vị trí cụ thể, hãy thử công thức dưới đây:

Quảng cáo
=SEARCH(C2,A2,9)

Ở đây, chúng tôi đã chỉ định đối số cuối cùng (start_num) là 9. Vì vậy, hàm SEARCH bắt đầu tìm kiếm từ Sparta (C2) từ vị trí 9 (từ ký tự khoảng trắng sau từ Ghost) trong chuỗi của ô A2 và trả về vị trí của từ tìm kiếm là 14.

Hãy nhớ rằng, khi đếm các vị trí, ký tự khoảng trắng cũng được bao gồm trong số đếm.

Khi Văn bản Tìm kiếm Xuất hiện Nhiều lần

Hãy thử một ví dụ khác. Nếu chúng ta muốn tìm vị trí của từ ‘God’, chúng ta có thể thử công thức dưới đây:

=SEARCH(C2,A3,2)

Số bắt đầu (start_num) ở đây là 2, vì vậy việc tìm kiếm bắt đầu từ ký tự ‘y’. Mặc dù có hai trường hợp của từ ‘God’ trong chuỗi, nó chỉ trả về vị trí của từ đầu tiên từ số bắt đầu. Do đó, đầu ra là 4.

Bây giờ, hãy thử thay đổi số bắt đầu thành 5:

=SEARCH(C2,A3,5)

Bây giờ, bạn sẽ nhận được kết quả là 9, vì tìm kiếm bắt đầu ở ký tự ‘o’ (trong trường hợp đầu tiên của từ God), và trường hợp đầu tiên của ‘God’ bị bỏ qua.

Quảng cáo

#VALUE! error 

Có hai trường hợp mà bạn sẽ nhận được lỗi ‘#VALUE!’ khi tìm kiếm văn bản bằng chức năng SEARCH:

  • Nếu từ tìm kiếm đã cho (find_text) không được tìm thấy trong chuỗi within_text đã chỉ định.
  • Nếu số bắt đầu (start_num) nhỏ hơn 0 hoặc lớn hơn độ dài của chuỗi inside_text.

Như bạn có thể thấy bên dưới, số bắt đầu cho tìm kiếm là 10. Cả hai trường hợp của từ đầy đủ ‘God’ đều đứng trước vị trí 10, do đó lỗi #VALUE! .

Trong ví dụ dưới đây, số bắt đầu vượt quá độ dài của chuỗi within_text, vì vậy chúng tôi nhận được lỗi #VALUE!.

Chức năng SEARCH có thể được sử dụng để tìm bất kỳ loại ký tự nào, ngay cả ký hiệu. Ví dụ: chúng tôi đã tìm kiếm vị trí của biểu tượng Trademark  (™) trong chuỗi đã cho và tìm thấy vị trí của nó là 20.

Tìm kiếm với các ký tự đại diện trong hàm SEARCH Excel

Hàm SEARCH hỗ trợ các ký tự đại diện – dấu hỏi (?), Dấu hoa thị (*) và dấu ngã (~). Dấu chấm hỏi (?) Đại diện cho bất kỳ ký tự đơn nào, dấu hoa thị (*) biểu thị bất kỳ chuỗi ký tự nào và dấu ngã (~) khớp với bất kỳ ký tự đại diện nào trong số hai ký tự đại diện còn lại.

Ví dụ 1:

Quảng cáo

Trong ví dụ dưới đây, ký tự đại diện (*) được sử dụng để tìm vị trí của từ ‘Pencils’ (Pen * S) trong chuỗi ở ô A13:

=SEARCH(D9,A13,1)

Ở đây từ tìm kiếm là ‘Pen * s’ (D9), vì vậy công thức tìm kiếm bất kỳ văn bản nào bắt đầu bằng ‘Pen’ và kết thúc bằng ‘s’ và có bất kỳ số ký tự nào ở giữa chúng trong ô A13. Nó khớp với văn bản ‘Pencils’ và trả về vị trí của nó là 12.

Ví dụ 2:

Khi chỉ định số bắt đầu (start_num), bạn cần chỉ định số bắt đầu chính xác để bắt đầu tìm kiếm.

Ví dụ: công thức dưới đây có thể tìm vị trí của văn bản ‘c*r’ trong chuỗi của ô A10:

=SEARCH(C2,A10,1)

Chúng tôi muốn tìm vị trí của ‘char’ trong từ ‘character’ thay vào đó chúng tôi đã tìm vị trí của ‘car’ trong ‘Wildcard’, là 5.

Để khắc phục điều này, chúng ta có thể thay đổi số bắt đầu tìm kiếm thành 8. Bây giờ, hàm bắt đầu tìm kiếm từ ký tự ‘d’ ở cuối ký tự đại diện và tìm vị trí của ‘Char’ trong ‘Characters’.

Quảng cáo

Ví dụ 3:

Một ví dụ khác trong đó ký tự đại diện được sử dụng trước từ tìm kiếm. Bây giờ, bất kể có bao nhiêu ký tự khác ở phía trước ‘war’ trong ô A3, nó sẽ trả về vị trí tìm kiếm là 1.

Ví dụ 4 :

Trong ví dụ dưới đây, câu hỏi (?) Được sử dụng để tìm vị trí của văn bản ‘PC940’ (?C94?) Trong chuỗi ở ô A12:

=SEARCH("?C94?",A12,1)

Trong đó ? biểu thị bất kỳ ký tự đơn nào, vì vậy công thức khớp với chuỗi ‘PC940’ nằm ở vị trí 7.

Sử dụng hàm SEARCH với các hàm khác

Hàm SEARCH thường được kết hợp với các hàm khác như MID, LEFT, RIGHT hoặc ISNUMBER để thực hiện các phép tính mạnh mẽ.

Tìm và trích xuất chuỗi bằng hàm SEARCH

Bạn có thể sử dụng hàm SEARCH với các hàm LEFT, RIGHT hoặc MID để định vị và trích xuất một chuỗi con trong chuỗi văn bản ở bên trái hoặc bên phải của một ký tự cụ thể hoặc giữa hai ký tự. Ví dụ: những sự kết hợp này rất hữu ích để tách danh sách tên đầy đủ thành tên, họ và tên đệm.

Quảng cáo

Trích xuất một chuỗi con trước (các) ký tự cụ thể bằng cách sử dụng các hàm SEARCH và LEFT

Nếu bạn có một chuỗi văn bản hoặc danh sách các chuỗi, bạn có thể sử dụng hàm SEARCH kết hợp với hàm LEFT để trích xuất một chuỗi con hoặc một phần của chuỗi vào một cột riêng biệt.

Hàm LEFT giúp bạn trích xuất một số ký tự cụ thể từ phía bên trái của chuỗi, bắt đầu bằng ký tự đầu tiên của chuỗi.

Cú pháp của hàm LEFT:

=LEFT(text,[num_chars])

Nó yêu cầu hai đối số:

  • text là chuỗi văn bản hoặc tham chiếu đến một ô có chứa các ký tự bạn muốn trích xuất.
  • num_chars là số ký tự bạn muốn trích xuất từ ​​trái sang phải trong ô đã cho text (bao gồm khoảng cách giữa các ký tự).

Giả sử bạn có một danh sách đầy đủ các tên trong một cột và bạn muốn trích xuất Last name thành các cột riêng biệt, bạn có thể thực hiện điều đó với các hàm LEN và SEARCH. Đây là cách nó hoạt động:

Cú pháp để trích xuất một chuỗi con trước một ký tự cụ thể :

Sử dụng công thức dưới đây (kết hợp giữa LEN và FIND) để trích xuất một chuỗi con trước một ký tự cụ thể:

Quảng cáo
=LEFT(text,SEARCH("char",text)-1)
  • text chỉ định chuỗi văn bản mà chúng ta muốn trích xuất một chuỗi con / văn bản. Nó có thể là một chuỗi văn bản hoặc một tham chiếu đến một ô có chuỗi.
  • char là ký tự cụ thể mà chúng tôi muốn xác định vị trí. 

Hm SEARCH tìm vị trí của ký tự được chỉ định trong chuỗi văn bản đã cho, sau đó 1 được trừ khỏi số vị trí đó (vị trí của ký tự được chỉ định) để xác định độ dài của chuỗi con cần trích xuất. Sau đó, độ dài được cung cấp cho LEFT để trích xuất số ký tự từ trái sang phải trong chuỗi.

Thí dụ:

Nhập công thức sau để trích xuất tên từ tên đầy đủ:

=LEFT(A2,SEARCH(" ",A2)-1)

Công thức trên sử dụng hàm SEARCH để xác định vị trí (là 7) của ký tự khoảng trắng (““) ở giữa họ và tên và trừ đi 1 để loại trừ chính khoảng trắng. Bây giờ chúng ta đã có độ dài của tên (6 ký tự ngoài cùng bên trái). Số này sau đó được cung cấp cho hàm LEFT để trả về số ký tự (6) từ trái sang phải trong chuỗi.

Nếu danh sách các chuỗi có mẫu giống như tất cả chúng đều có các ký tự khoảng trắng ở giữa. Sau đó, bạn có thể sử dụng công thức LEFT và FIND của Excel để trích xuất chuỗi từ toàn bộ cột bằng cách sử dụng tính năng tự động điền mà không cần phải chỉ định charđối số cho mỗi công thức.

Để làm điều đó, hãy chọn ô công thức (B2) và kéo chốt điền (hình vuông nhỏ màu xanh lục ở cuối ô đã chọn) xuống các ô khác để áp dụng công thức này cho một cột. Bây giờ tất cả các tên đã được trích xuất vào cột B như hình dưới đây:

Trích xuất một chuỗi con sau (các) ký tự cụ thể bằng cách sử dụng SEARCH và RIGHT

Nếu bạn muốn trích xuất một chuỗi con sau một ký tự cụ thể, bạn cần sử dụng kết hợp các hàm RIGHT, SEARCH và LEN. Hàm SEARCH và LEN được lồng trong đối số num_char của hàm RIGHT để tìm số ký tự cần trích xuất và hàm RIGHT trích xuất các ký tự đó.

Quảng cáo

Cú pháp để trích xuất một chuỗi con sau một ký tự cụ thể :

=RIGHT(text,LEN(text)-SEARCH("char",text))

Giả sử chúng ta có một cột tên đầy đủ và bạn muốn trích xuất Họ (Last name) thành các cột riêng biệt, bạn có thể làm điều đó với công thức sau:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Trong công thức trên, hàm SEARCH trả về vị trí của ký tự khoảng trắng ”, là 7 và hàm LEN tìm tổng số ký tự trong chuỗi (độ dài chuỗi). Sau đó, vị trí của khoảng trắng được trừ khỏi tổng số ký tự trong chuỗi để tìm độ dài của họ, được cung cấp cho hàm RIGHT để trích xuất nhiều ký tự đó từ cuối chuỗi.

Sau khi họ được trích xuất sang một cột riêng biệt, hãy kéo chốt điền xuống các ô khác để áp dụng công thức này cho cột. Bây giờ tất cả các Last name đã được trích xuất vào cột C như hình dưới đây:

Trích xuất một chuỗi con giữa hai ký tự bằng cách sử dụng hàm MID và SEARCH

Nếu bạn muốn trích xuất phần giữa của chuỗi văn bản, bạn có thể làm điều đó với sự trợ giúp của các hàm MID và SEARCH.

Hàm MID trong Excel

Hàm MID Excel được sử dụng để trích xuất phần giữa của chuỗi. Để làm điều đó, nó yêu cầu chuỗi văn bản, điểm bắt đầu (vị trí) và số ký tự cần trích xuất.

Quảng cáo

Cú pháp:

=MID(text,start_num,num_chars)
  • text chỉ định chuỗi văn bản mà chúng ta muốn trích xuất một chuỗi con / văn bản. Nó có thể là một chuỗi văn bản hoặc một tham chiếu đến một ô có chuỗi.
  • start_num chỉ định vị trí trong chuỗi văn bản từ nơi bạn muốn bắt đầu trích xuất. Nếu bị bỏ qua, tìm kiếm sẽ bắt đầu từ ký tự đầu tiên của chuỗi within_text.
  • num_chars là số ký tự bạn muốn trích xuất từ ​​trái sang phải trong danh sách đã cho text.

Các đối số start_num và num_chars có thể được hàm SEARCH cung cấp cho hàm MID để trích xuất một chuỗi con giữa hai ký tự.

Hãy để chúng tôi xem hàm MID hoạt động như thế nào với ví dụ đơn giản sau:

=MID(A2,10,4)

Công thức đếm các ký tự trong ô A2 từ trái sang phải cho đến khi nó đến ký tự thứ 10 và sau đó nó trả về 7 ký tự tiếp theo (bao gồm cả ký tự thứ 10).

Để trích xuất một chuỗi con giữa hai ký tự có MID và SEARCH , hãy sử dụng cú pháp sau:

=MID(text,SEARCH("char",text)+1,SEARCH("char",text)-SEARCH("char",text)-1)
  • text: Một chuỗi mà từ đó chúng ta muốn trích xuất một chuỗi con, đây có thể là một chuỗi văn bản hoặc một tham chiếu đến một ô có một chuỗi.
  • char: Một ký tự cụ thể mà chúng tôi muốn xác định vị trí. 

Ví dụ 1:

Giả sử bạn là cột ID sản phẩm và bạn muốn trích xuất số ID giữa các ký tự ‘-‘ và ‘/’.

Quảng cáo

Chúng ta cần tìm vị trí của hai ký tự được chỉ định, sau đó trừ vị trí của ký tự thứ 2 cho vị trí của ký tự thứ nhất, và trừ 1 từ kết quả để xác định có bao nhiêu ký tự cần trích xuất bắt đầu từ vị trí của ký tự đầu tiên.

Để trích xuất chuỗi giữa giữa hai ký tự, hãy nhập công thức này vào một ô trống:

=MID(A2,SEARCH("-",A2)+1,SEARCH("/",A2)-SEARCH("-",A2)-1)

Giải trình:

  • A2 là ô chứa chuỗi văn bản gốc mà từ đó chúng ta muốn trích xuất chuỗi con.
  • SEARCH("-",A2)+1 (start_num) xác định vị trí của ký tự được chỉ định đầu tiên (-) và thêm 1 để bắt đầu trích xuất từ ​​ký tự tiếp theo (start_num = 5).
  • SEARCH("/",A2)-SEARCH("-",A2)-1 (num_chars) tìm độ dài của chuỗi con mà chúng ta muốn trích xuất giữa các ký tự ‘-‘ và ‘/’ bằng cách trừ vị trí của ‘/’ (13) khỏi vị trí của ‘-‘ (4) và trừ 1 từ kết quả. Điều này sẽ cho hàm MID biết có bao nhiêu ký tự cần trích xuất.

Bây giờ, hàm MID biết có bao nhiêu ký tự để trích xuất từ ​​chuỗi và bắt đầu từ đâu. Nó sẽ trả về chuỗi giữa trong ô C2.

Sau đó, bạn có thể sao chép công thức vào phần còn lại của các ô để trích xuất chuỗi giữa cho cả cột.

Ví dụ 2 :

MID và SEARCH thực sự hữu ích khi trích xuất tên đệm từ danh sách tên đầy đủ. Để trích xuất tên đệm, hãy sử dụng công thức sau:

Quảng cáo
=MID(A2,SEARCH(" ",A2)+1,SEARCH(" ",A2,SEARCH(" ",A2)+1)-SEARCH(" ",A2)-1)

Vấn đề là cả hai ký tự được chỉ định đều là ký tự khoảng trắng (giống nhau), vì vậy công thức sẽ không thể phân biệt đâu là ký tự, và nó sẽ dẫn đến lỗi #VALUE !. Để khắc phục điều này, chúng tôi đã lồng một hàm SEARCH bên trong một hàm SEARCH khác và thêm 1 vào đối số ‘num_chars’ để tìm vị trí của ký tự khoảng trắng thứ hai.

  • SEARCH(" ",A2)+1 xác định điểm bắt đầu để trích xuất bằng cách thêm 1 vào vị trí của ký tự khoảng trắng đầu tiên.
  • SEARCH(" ",A2,SEARCH(" ",A2)+1)-SEARCH(" ",A2)-1 trừ vị trí của khoảng trắng thứ 2 với vị trí của khoảng trắng thứ nhất và trừ đi 1 từ kết quả để loại bỏ một khoảng trắng ở cuối. Giá trị kết quả cho công thức biết có bao nhiêu ký tự cần trích xuất.

Bây giờ với chuỗi văn bản gốc, số bắt đầu và số ký tự, hàm MID sẽ trích xuất tên đệm từ tên đầy đủ (A2).

Tìm lần xuất hiện hoặc vị trí thứ N của một ký tự trong một chuỗi bằng cách sử dụng hàm SEARCH

Nếu bạn đang cố gắng tìm vị trí của một ký tự hoặc văn bản xuất hiện nhiều lần trong một chuỗi, thì hàm SEARCH sẽ chỉ trả về kết quả khớp đầu tiên của ký tự / văn bản đó. Tuy nhiên, khi bạn kết hợp các hàm SEARCH và SUBSTITUTE, bạn có thể tìm thấy vị trí hoặc vị trí xuất hiện thứ n (chẳng hạn như trường hợp thứ hai hoặc thứ ba) của một ký tự cụ thể (hoặc chuỗi ký tự) trong chuỗi văn bản một cách dễ dàng.

Đây là công thức chung để tìm vị trí của lần xuất hiện thứ N của một ký tự:

=SEARCH(CHAR,SUBSTITUTE(text, character, CHAR, [instance_num])) 

ở đâu

  • CHAR là một hàm trả về một ký hiệu dựa trên mã ASCII của nó. Bạn có thể sử dụng bất kỳ mã ASCII nào hoặc ký hiệu mà bạn chắc chắn sẽ không xuất hiện trong chuỗi.
  • text là chuỗi văn bản hoặc tham chiếu đến một ô chứa chuỗi mà bạn muốn tìm lần xuất hiện thứ n.
  • character là ký tự mà bạn muốn tìm lần xuất hiện thứ n.
  • [instance_num] chỉ định sự xuất hiện của (các) ký tự hoặc chuỗi văn bản mà bạn muốn tìm.

Ví dụ 1:

Trong ví dụ dưới đây, chúng tôi muốn tìm lần xuất hiện thứ 2 của ký tự ‘/’ với công thức sau:

Quảng cáo
=SEARCH("$",SUBSTITUTE(A1,"/","$",2))

Hàm SUBSTITUTE thực sự tìm kiếm một ký tự hoặc văn bản và thay thế nó bằng một ký tự hoặc văn bản khác. Trong công thức trên, chúng tôi đang thay thế ký tự (/) bằng ‘$’, ký tự này sẽ không hiển thị trong chuỗi. Vì vậy, khi hàm SUBSTITUTE thay thế lần xuất hiện thứ 2 của ký tự ‘/’ trong chuỗi cho ký hiệu ‘$’, hàm SEARCH sẽ trả về vị trí của ký tự đó.

Bạn cũng có thể sử dụng mã CHAR ASCII trong CHAR đối số của công thức thay thế các ký tự tìm kiếm (/) để nhận được kết quả tương tự.

Ví dụ 2:

Một công thức khác có thể giúp bạn tìm lần xuất hiện thứ n của một ký tự cụ thể từ chuỗi văn bản.

Công thức dưới đây sẽ trả về vị trí của lần xuất hiện thứ 3 của “e” trong ô A1:

=SEARCH("e",A13,SEARCH("e",A13)+2)

Công thức trên sẽ trả về vị trí của ‘e’ thứ 3 là 23. Bạn có thể chỉ định sự xuất hiện trong công thức bằng cách thay đổi đối số cuối cùng (2) cho phù hợp. Nếu bạn muốn tìm lần xuất hiện đầu tiên của “e”, hãy thay đổi 2 thành 0. Và để tìm lần xuất hiện thứ hai của “e”, hãy thay đổi 2 thành 1, v.v.

Kết hợp ISNUMBER với  chức năng SEARCH để kiểm tra văn bản cụ thể

Như chúng ta đã biết, hàm SEARCH tìm kiếm một chuỗi con cụ thể trong một chuỗi và trả về vị trí số của nó nếu văn bản được tìm thấy, nếu không nó sẽ trả về lỗi #VALUE! . Hàm ISNUMBER kiểm tra xem ô có chứa số hay không. Nếu có, nó trả về TRUE, ngược lại, nó trả về FALSE.

Quảng cáo

Tuy nhiên, khi hàm ISNUMBER kết hợp với hàm SEARCH, nó có thể kiểm tra xem một ô có chứa văn bản cụ thể hay không và trả về TRUE nếu văn bản được tìm thấy, nếu không nó sẽ trả về FALSE.

Đây là công thức chung để kiểm tra xem một ô có chứa văn bản cụ thể hay không:

=ISNUMBER(SEARCH(substring,text))

Giải thích

  • substring là chuỗi văn bản mà bạn muốn tìm
  • text là ô hoặc chuỗi mà bạn muốn kiểm tra chuỗi con.

Thí dụ:

Trong tập dữ liệu dưới đây, chúng tôi muốn tìm xem từ Cow có tồn tại trong cột A hay không:

=ISNUMBER(SEARCH("Cow",A2))

Đầu tiên, nhập công thức vào ô A2 và tự động điền công thức vào cột. Hàm ISNUMBER kiểm tra xem chuỗi ‘Cow’ có xuất hiện trong ô A2 hay không và trả về FALSE.

Hàm SEARCH kiểm tra ô A2 để tìm văn bản ‘Cow’ và trả về giá trị ‘#VALUE!’ (vì không có dòng chữ Cow). Giá trị!’ không phải là một số nên hàm ISNUMBER trả về giá trị ‘FALSE’. Trong ô B2, hàm SEARCH kiểm tra từ ‘Bò’ và trả về số vị trí của nó, vì vậy hàm ISNUMBER trả về ‘TRUE’.

Quảng cáo

Chúng ta cũng có thể sử dụng tham chiếu ô để nhập chuỗi vào công thức:

=ISNUMBER(SEARCH(B$1,A2))

Kiểm tra Văn bản Cụ thể với hàm IF, ISNUMBER và SEARCH

Nếu bạn muốn nhận được một cái gì đó khác với TRUE hoặc FALSE khi một chuỗi con được tìm thấy trong một chuỗi, bạn có thể sử dụng hàm IF với ISNUMBER và SEARCH.

Ví dụ: chúng tôi sẽ cố gắng tìm xem mỗi ô trong cột A có chứa từ ‘Cow’ hay không và trả về “Found” nếu ô chứa văn bản đó và “Not Found” nếu không:

=IF(ISNUMBER(SEARCH(B$1,A2)), "Found","Not Found")

Bạn có thể sao chép công thức trong ô B2 sang các ô còn lại bằng cách sử dụng chốt điền. Trong công thức, hàm SEARCH kiểm tra giá trị trong ô B1 so với ô A1 và trả về lỗi. Vì vậy, hàm ISNUMBER trả về FALSE. Kết quả là, hàm IF trả về ‘Not Found’.

Nhận decor tiệc sinh nhật theo yêu cầu

Xem thêm :

Xem thêm về:

Quảng cáo
Chia sẻ suy nghĩ, quan điểm của bạn

Leave a reply

Tìm kiếm

Copyright Saohaivuong All Rights Reserved.

Sao Hải Vương
Logo